Data Binding

<mx:Binding source="source.text" destination="destination.text" />
<mx:TextInput id="source" />
<mx:TextInput id="destination" />

OR

<mx:TextInput id="source" />
<mx:TextInput id="destination" text="{source.text}" />

* * *

<mx:Binding source="source.text" destination="destination.text"/>
<mx:Binding source="source2.text" destination="destination.text"/>
<mx:TextInput id="source"/>
<mx:TextInput id="source2"/>
<mx:TextInput id="destination"/>

Simple data binding:

<mx:ComboBox id="c" dataProvider="{myArray}" />
<mx:ViewStack id="v" selectedIndex="{c.selectedIndex}">
<mx:Canvas>
<mx:Label text="1"/>
</mx:Canvas>
<mx:Canvas>
<mx:Label text="2"/>
</mx:Canvas>
</mx:ViewStack>

OR

<mx:ComboBox id="c" dataProvider="{myArray}" />
<mx:Binding source="c.selectedIndex" destination="v2.selectedIndex" />
<mx:ViewStack id="v2">
<mx:Canvas>
<mx:Label text="1"/>
</mx:Canvas>
<mx:Canvas>
<mx:Label text="2"/>
</mx:Canvas>
</mx:ViewStack>

String concatenation:

<mx:TextInput id="fname" />
<mx:TextInput id="lname" />
<mx:Label text="{'First Name: ' + fname.text}" />
<mx:Label text="{'Full Name: ' + fname.text + ' ' + lname.text}" />

OR

<mx:TextInput id="fname" />
<mx:Binding source="{'First Name: ' + fname.text}" destination="destination.text" />
<mx:Label id="destination"/>

Calculations:

<mx:NumericStepper id="quantity" />
<mx:TextInput id="price" />
<mx:Label text="{'Total: ' + quantity.value * Number(price.text)}" />

OR

<mx:NumericStepper id="quantity" />
<mx:TextInput id="price" />
<mx:Binding source="{'Total: ' + quantity.value * Number(price.text)}" destination="destination.text" />
<mx:Label id="destination"/>

Conditional:

<mx:NumericStepper id="quantity" />
<mx:Label text="{(quantity.value % 2) ? 'Odd' : 'Even'}" />

OR

<mx:NumericStepper id="quantity" />

<mx:Binding source="{(quantity.value % 2) ? 'Odd' : 'Even'}" destination="destination.text" />

<mx:Label id="destination"/>

cacheAsBitmap для AS2 ручками. AS2

Давно, работая с AS3, убедился, что очень эффективно кэшировать статические мувики вручную - сохранять снимок мувика в BitmapData и заменять на сцене сложный клип на полученное растровое изображение. Выигрыш производительности просто неимоверный! Я даже сделал специальный механизм, который сканировал сцену на предмет таких клипов (помеченных особым именем) и кэшировал их таким способом. Причем, штатный cacheAsBitmap работает совершенно отвратительно и против ручного метода, просто курит в затяг.

И вот, на днях, доделывая одну ужасно тормозную заставку на flash 8, решил применить это дело и для AS2. Вот простейший код, который вставляется во фрейм мувика, на котором мувик надо закешировать (правда внешний контроль над ним будет потерян, но это уже другая история):

import flash.display.BitmapData;
stop();
var bitmap:BitmapData = new BitmapData(this._width,this._height,false);
bitmap.draw(this);
this._parent.attachBitmap(bitmap,this.getDepth());
this.unloadMovie();

Список без подсветки и выделения элементов. Flex

Код к статье Список без подсветки и выделения элементов.

package InterfaceClasses
{
import flash.display.Sprite;
import mx.controls.TileList;
import mx.controls.listClasses.IListItemRenderer;
public class TransparentTileList extends TileList
{
override protected function drawSelectionIndicator(
indicator:Sprite, x:Number, y:Number, width:Number,
height:Number, color:uint,
itemRenderer:IListItemRenderer):void
{
return;
}
override protected function drawHighlightIndicator(
indicator:Sprite, x:Number, y:Number, width:Number,
height:Number, color:uint,
itemRenderer:IListItemRenderer):void
{
return;
}
}
}

Как наложить цвет на изображение при помощи фильтра

На сцене лежит клип "item".
На него накладывается цвет, к примеру: "0xCC9933FF".

package {
import flash.display.DisplayObject;
import flash.display.MovieClip;
import flash.filters.ColorMatrixFilter;

public class ColorMatrixFilterExample extends MovieClip {

public function ColorMatrixFilterExample() {
this.applyColor(0xCC9933FF, this.getChildByName("item"));
}

private function applyFilter(child:DisplayObject, matrix:Array):void {
var filter:ColorMatrixFilter = new ColorMatrixFilter(matrix);
var filters:Array = new Array();
filters.push(filter);
child.filters = filters;
}

private function applyColor(rgb:uint,renderer:DisplayObject):void {
var matrix:Array = new Array();

matrix = matrix.concat([((rgb>>24)&0xFF)/0xFF, 0, 0, 0, 0]); // red
matrix = matrix.concat([0, ((rgb>>16)&0xFF)/0xFF, 0, 0, 0]); // green
matrix = matrix.concat([0, 0, ((rgb>>8)&0xFF)/0xFF, 0, 0]); // blue
matrix = matrix.concat([0, 0, 0, ((rgb)&0xFF)/0xFF, 0]); // alpha
applyFilter(renderer, matrix);
}
}
}

Организация метаданных класса

Информация для статьи Хороший стиль Flex-программирования. Структура файла.

//--------------------------------------
// Events
//--------------------------------------
/
**
* ASDoc comment.
*/
[Event
/**
* ASDoc comment.
*/
[Event
//--------------------------------------
// Styles
//--------------------------------------
/**
* ASDoc comment.
*/
[Style
/**
* ASDoc comment.
*/
[Style]
//--------------------------------------
// Effects
//--------------------------------------
/**
* ASDoc comment.
*/
[Effect
/**
* ASDoc comment.
*/
[Effect]
//--------------------------------------
// Excluded APIs
//--------------------------------------
[Exclude(name="horizontalAlign", kind="style")]
[Exclude(name="verticalAlign", kind="style")]
//--------------------------------------
// Other metadata
//--------------------------------------
[DefaultBindingProperty(source="text", destination="text")]
[IconFile("Text.png")]

Блок Copyright

Информация для статьи Хороший стиль Flex-программирования. Структура файла.

////////////////////////////////////////////////////////////////////////////////
//
// ADOBE SYSTEMS INCORPORATED
// Copyright 2008 Adobe Systems Incorporated
// All Rights Reserved.
//
// NOTICE: Adobe permits you to use, modify, and distribute this file
// in accordance with the terms of the license agreement accompanying it.
//
////////////////////////////////////////////////////////////////////////////////

Стиль без скина. MXML

.styleName {
skin: ClassReference(null);
}


HandCursor над кнопкой. MXML

<mx:Button label="Button" useHandCursor="true" buttonMode="true" mouseChildren="false" id="button_name" />

"Ручной" cacheAsBitmap. AS2

Код для статьи "Ручной" cacheAsBitmap. AS2.

Пример использования:

import flash.display.BitmapData;
import flash.geom.Matrix;
import flash.geom.ColorTransform;

var bmp_data:BitmapData = new BitmapData(this._width,this._height,false,0);
bmp_data.draw(this,new Matrix(),new ColorTransform(),"normal",new Rectangle(0,0,this._width,this._height),true);

var name:String;
for (name in this)
if (this[name] instanceof MovieClip) {
var movie:MovieClip = this[name];
movie.unloadMovie();
delete this[name];
}

this._height-=0.5;
this.attachBitmap(bmp_data,1,"auto", true);

Псевдо-генератор случайных чисел. AS3

package org.racer.utils
{
/**
* Псевдо-генератор случайных чисел.
* Получает гамму случайных чисел, и по запросу, выдает каждый последующий элемент гаммы
* Класс представляет только статические методы и не позволяет себя инстанцировать.
*
* @author Evgeny [Racer] Simonov
* @version 1.0
*/
public class TGammaRandom {

/**
* При отсутствии гаммы случайных чисел, random возвращает -1
*/
static public const RETURN_ERROR_MODE:int=0;

/**
* При отсутствии гаммы случайных чисел, random возвращает Math.random();
*/
static public const RETURN_RANDOM_MODE:int=1;

/**
* При отсутствии гаммы случайных чисел, random генерирует исключение
*/
static public const THROW_EXCEPTION_MODE:int=2;

/**
* @private
* Текущий элемент
*/
static private var __current:Number=0;

/**
* @private
* Режим реакции на ошибку в случае неустановленной гаммы случайных чисел
* true - генерируется исключение, false - в результат выдается Math.random();
*/
static private var __strict_mode:int=THROW_EXCEPTION_MODE;

/**
* Режим реакции на ошибку в случае неустановленной гаммы случайных чисел
* true - генерируется исключение, false - в результат выдается Math.random();
*/
static public function set strict_mode(value:int):void {
__strict_mode=value;
}

/**
* @private
*/
static public function get strict_mode():int {
return __strict_mode;
}

/**
* @private
* Гамма случайных чисел
*/
static private var __gamma:Array=null;

/**
* Гамма случайных чисел
*/
static public function set gamma(value:Array):void {
__gamma=value;
}

/**
* @private
*/
static public function get gamma():Array {
return __gamma;
}

/**
* Конструктор. Никогда не вызывается.
*/
public function TGammaRandom() {
throw new Error("Класс TGammaRandom инстанцировать нельзя. Все методы класса являются статическими.");
}

/**
* Возвращает значение из гаммы случайных чисел.
*
* @return Случайное значение
*/
static public function random():Number {
if ((__gamma==null)||(__gamma.length==0)) {
switch (__strict_mode) {
case RETURN_ERROR_MODE:
return -1;
break;
case RETURN_RANDOM_MODE:
return Math.random();
break;
case THROW_EXCEPTION_MODE:
throw new Error("Гамма случайных чисел не установлена, либо пуста. Невозможно возвратить случайное число.");
break;
}
}
if (__current>=__gamma.length) __current=0;
return __gamma[__current++];
}
}
}

Серверный скрипт изменения значения переменной комнаты с оповещением всех пользователей зоны. SmartFoxServer API

Получить запрос на изменение переменной комнаты, изменить ее и оповестить всех авторизованных в зоне пользователей об изменении (дело в том, что стандартный метод SFS Flash API изменения переменной комнаты оповещает только пользователей, находящихся в изменяемой комнате).

function init() {
trace("Initialization Zone Level Extension")
zone=_server.getCurrentZone();
}

function handleRequest(cmd, params, user, fromRoom) {
trace("Zone Level Extension received request: cmd="+cmd+" params="+params+" user="+user+" fromRoom="+fromRoom);

switch (cmd) {
case "setrv":
trace("Room "+zone.getRoom(fromRoom).getName()+" variable changed: "+params.name+". Setting the variable and sending broadcast for all users.");
_server.setRoomVariables(zone.getRoom(fromRoom), user, [params], false, false);
var response={}
response._cmd="chgrv"
response.r_id=fromRoom
response.name=params.name
response.val=params.val
_server.sendResponse(response, fromRoom, null, zone.getUserList().toArray())
break;
}
}

Добавляем ссылку в контекстное меню Flash. ContextMenu. AS2

_root.menu=new ContextMenu();
var context_menu:ContextMenu = new ContextMenu();
context_menu.customItems.push(new ContextMenuItem("Some link title", this.onContextMenu));
_root.menu=context_menu;

. . .

public function onContextMenu() {
_root.getURL("http://www.somelink.ru/" );
}

Представление компонентов в виде списка. Flex

Создать ItemVO.as с кодом:

package
{
import flash.events.IEventDispatcher;
import flash.events.EventDispatcher;
[Bindable]
public class ItemVO extends EventDispatcher
{
public var label : String;
public var checked : Boolean;
}
}

Создать CheckBoxItemRender.mxml с кодом:

<?xml version="1.0" encoding="utf-8"?>
<?xml:namespace prefix = mx /><mx:canvas height="20" width="100" mx="http://www.adobe.com/2006/mxml">
<mx:checkbox id="checker" change="{data.checked = checker.selected}" selected="{data.checked}" label="{data.label}"></mx:checkbox>
</mx:canvas>

Создать ComponentListTest.mxml с кодом:

<?xml version="1.0" encoding="utf-8"?>
<!-- Tree control example. -->
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" xmlns:local="*" layout="vertical">
<mx:Script>
<![CDATA[
public function clearItems() : void
{
for (var i : Number=0; i<arcoltest.length; i++)
{
arcoltest.getItemAt(i).checked = false;
}
}
]]>
</mx:Script>
<mx:ArrayCollection id="arcoltest">
<local:ItemVO label="qewqw" checked="true" />
<local:ItemVO label="1" checked="true" />
<local:ItemVO label="2" checked="true" />
<local:ItemVO label="1231" checked="true" />
<local:ItemVO label="qweqwe" checked="true" />
</mx:ArrayCollection>
<mx:List dataProvider="{arcoltest}" itemRenderer="CheckBoxItemRender" />
<mx:Button label="Clear all" click="clearItems()"/>
</mx:Application>

Обработчик события. MXML

Можно добавить обработчик события в скрипте:

video_playback.addEventListener(MouseEvent.MOUSE_OVER,this.onMouseOver);

Или прямо в теге:

<mx:videodisplay id="video_playback" height="302" width="697" y="74" x="37.5" autoplay="true" mouseover="onMouseOver(event);"></mx:videodisplay>

Класс Dictionary. AS3

Пример перебора элементов Dictionary:

import flash.utils.Dictionary;

var a:Object = new Object();
var b:Object = new Object();

var dict:Dictionary = new Dictionary();
dict[a] = 1; // dict[a] = 1;
dict[b] = 2; // dict[b] = 2;

for (var prop:* in dict) {
trace(prop); // traces: [object Object], [object Object]
trace(dict[prop]); // traces: 1, 2
}

Источник.

Удаление элемента из Dictionary:

delete dict[a];

Код для статьи "Делаем прелоадер для Flex-приложения". AS3.

Код основного класса MainClass:

package {
import flash.display.Sprite;
import flash.display.Bitmap;

[Frame(factoryClass="MyFactory")]
public class FrameTest extends Sprite
{
[Embed(source="big_asset.jpg")]
private var Asset:Class;

public function FrameTest()
{
init();
}

public function init():void
{
var asset:Bitmap = new Asset();
addChild(asset);
}
}
}

Код класса фабрики MyFactoryClass:

package
{
import flash.display.DisplayObject;
import flash.display.MovieClip;
import flash.display.StageAlign;
import flash.display.StageScaleMode;
import flash.events.Event;
import flash.utils.getDefinitionByName;

public class MyFactory extends MovieClip
{
public function MyFactory()
{
stop();
stage.scaleMode = StageScaleMode.NO_SCALE;
stage.align = StageAlign.TOP_LEFT;
addEventListener(Event.ENTER_FRAME, onEnterFrame);
}

public function onEnterFrame(event:Event):void
{
graphics.clear();
if(framesLoaded == totalFrames)
{
removeEventListener(Event.ENTER_FRAME, onEnterFrame);
nextFrame();
init();
}
else
{
var percent:Number = root.loaderInfo.bytesLoaded / root.loaderInfo.bytesTotal;
graphics.beginFill(0);
graphics.drawRect(0, stage.stageHeight / 2 - 10,
stage.stageWidth * percent, 20);
graphics.endFill();
}
}

private function init():void
{
var mainClass:Class = Class(getDefinitionByName("FrameTest"));
if(mainClass)
{
var app:Object = new mainClass();
addChild(app as DisplayObject);
}
}
}
}

Преобразование цветного изображения в чернобелое с использованием ColorMatrixFilter. AS3

Один из способов преобразования цветного изображения в оттенки серого - установить пропорции цветов R:G:B в отношении 3:6:1 соответственно.

BMP - имя класса изображения в библиотеке.

var bmp:BitmapData = new BitmapData(1600, 1200);
var b:Bitmap = new Bitmap(bmp);
this.addChild(b);
var arr:Array = [
0.3, 0.6, 0.1, 0.0, 0.0,
0.3, 0.6, 0.1, 0.0, 0.0,
0.3, 0.6, 0.1, 0.0, 0.0,
0.0, 0.0, 0.0, 1.0, 0.0
];
var cmf:ColorMatrixFilter = new ColorMatrixFilter(arr);
bmp.applyFilter(new BMP(1600, 1200), new Rectangle(0, 0, bmp.width,
bmp.height), new Point(0, 0), cmf);

Загружаемый растр. Как включить сглаживание при трансформациях. AS2

//this.__display - клип, в который только что было загружено растровое изображение

public function makeBitmap() {

//Сохраняем изображение в BitmapData с включенным сглаживанием
var bmp_data:BitmapData = new BitmapData(this.__display._width,this.__display._height,true,0);
bmp_data.draw(this.__display,new Matrix(),new ColorTransform(),"normal",new Rectangle(0,0,this.__display._width,this.__display._height),true);

//Очищаем клип от загруженных данных (возможно есть более правильный способ)
var display_parent:MovieClip=this.__display._parent;
var display_name:String=this.__display._name;
var display_depth:Number=this.__display.getDepth();
this.__display.removeMovieClip();
this.__display=display_parent.createEmptyMovieClip(display_name,display_depth);

//Выводим растр в очищенный клип
this.__display.attachBitmap(bmp_data,0,"auto", true);
}

Ждем следующего фрейма для получения полноценного доступа к свойствам загруженного клипа. AS2

Особенность использования onLoadComplete вместо onLoadInit

private function waitForOneFrame() {
this.__display.onEnterFrame=Delegate.create(this,this.afterOneFrame);
}

private function afterOneFrame() {
this.__display.onEnterFrame=null;
//Есть доступ ко всем свойствам
}

private function onLoadComplete() {
this.waitForOneFrame();
}

Вращение клипа относительно любой точки

var angle=0.1;
var vector_x=mc._x-pointx; var vector_y=mc._y-pointy;

mc.onEnterFrame=function(){
var cos=Math.cos(angle);
var sin=Math.sin(angle);
var vector_rotate_x=vector_x*cos-vector_y*sin;
var vector_rotate_y=vector_x*sin+vector_y*cos;
vector_x=vector_rotate_x;
vector_y=vector_rotate_y;
mc._x=vector_rotate_x+pointx;
mc._y=vector_rotate_y+pointy;
mc._rotation+=angle*180/Math.PI;
}